030a954ed292a59feae0bbf8437f370127b22bd6
[linux-drm-fsl-dcu.git] / include / asm-generic / vmlinux.lds.h
1 /*
2  * Helper macros to support writing architecture specific
3  * linker scripts.
4  *
5  * A minimal linker scripts has following content:
6  * [This is a sample, architectures may have special requiriements]
7  *
8  * OUTPUT_FORMAT(...)
9  * OUTPUT_ARCH(...)
10  * ENTRY(...)
11  * SECTIONS
12  * {
13  *      . = START;
14  *      __init_begin = .;
15  *      HEAD_TEXT_SECTION
16  *      INIT_TEXT_SECTION(PAGE_SIZE)
17  *      INIT_DATA_SECTION(...)
18  *      PERCPU(PAGE_SIZE)
19  *      __init_end = .;
20  *
21  *      _stext = .;
22  *      TEXT_SECTION = 0
23  *      _etext = .;
24  *
25  *      _sdata = .;
26  *      RO_DATA_SECTION(PAGE_SIZE)
27  *      RW_DATA_SECTION(...)
28  *      _edata = .;
29  *
30  *      EXCEPTION_TABLE(...)
31  *      NOTES
32  *
33  *      BSS_SECTION(0, 0, 0)
34  *      _end = .;
35  *
36  *      STABS_DEBUG
37  *      DWARF_DEBUG
38  *
39  *      DISCARDS                // must be the last
40  * }
41  *
42  * [__init_begin, __init_end] is the init section that may be freed after init
43  * [_stext, _etext] is the text section
44  * [_sdata, _edata] is the data section
45  *
46  * Some of the included output section have their own set of constants.
47  * Examples are: [__initramfs_start, __initramfs_end] for initramfs and
48  *               [__nosave_begin, __nosave_end] for the nosave data
49  */
50
51 #ifndef LOAD_OFFSET
52 #define LOAD_OFFSET 0
53 #endif
54
55 #ifndef SYMBOL_PREFIX
56 #define VMLINUX_SYMBOL(sym) sym
57 #else
58 #define PASTE2(x,y) x##y
59 #define PASTE(x,y) PASTE2(x,y)
60 #define VMLINUX_SYMBOL(sym) PASTE(SYMBOL_PREFIX, sym)
61 #endif
62
63 /* Align . to a 8 byte boundary equals to maximum function alignment. */
64 #define ALIGN_FUNCTION()  . = ALIGN(8)
65
66 /*
67  * Align to a 32 byte boundary equal to the
68  * alignment gcc 4.5 uses for a struct
69  */
70 #define STRUCT_ALIGN() . = ALIGN(32)
71
72 /* The actual configuration determine if the init/exit sections
73  * are handled as text/data or they can be discarded (which
74  * often happens at runtime)
75  */
76 #ifdef CONFIG_HOTPLUG
77 #define DEV_KEEP(sec)    *(.dev##sec)
78 #define DEV_DISCARD(sec)
79 #else
80 #define DEV_KEEP(sec)
81 #define DEV_DISCARD(sec) *(.dev##sec)
82 #endif
83
84 #ifdef CONFIG_HOTPLUG_CPU
85 #define CPU_KEEP(sec)    *(.cpu##sec)
86 #define CPU_DISCARD(sec)
87 #else
88 #define CPU_KEEP(sec)
89 #define CPU_DISCARD(sec) *(.cpu##sec)
90 #endif
91
92 #if defined(CONFIG_MEMORY_HOTPLUG)
93 #define MEM_KEEP(sec)    *(.mem##sec)
94 #define MEM_DISCARD(sec)
95 #else
96 #define MEM_KEEP(sec)
97 #define MEM_DISCARD(sec) *(.mem##sec)
98 #endif
99
100 #ifdef CONFIG_FTRACE_MCOUNT_RECORD
101 #define MCOUNT_REC()    . = ALIGN(8);                           \
102                         VMLINUX_SYMBOL(__start_mcount_loc) = .; \
103                         *(__mcount_loc)                         \
104                         VMLINUX_SYMBOL(__stop_mcount_loc) = .;
105 #else
106 #define MCOUNT_REC()
107 #endif
108
109 #ifdef CONFIG_TRACE_BRANCH_PROFILING
110 #define LIKELY_PROFILE()        VMLINUX_SYMBOL(__start_annotated_branch_profile) = .; \
111                                 *(_ftrace_annotated_branch)                           \
112                                 VMLINUX_SYMBOL(__stop_annotated_branch_profile) = .;
113 #else
114 #define LIKELY_PROFILE()
115 #endif
116
117 #ifdef CONFIG_PROFILE_ALL_BRANCHES
118 #define BRANCH_PROFILE()        VMLINUX_SYMBOL(__start_branch_profile) = .;   \
119                                 *(_ftrace_branch)                             \
120                                 VMLINUX_SYMBOL(__stop_branch_profile) = .;
121 #else
122 #define BRANCH_PROFILE()
123 #endif
124
125 #ifdef CONFIG_EVENT_TRACING
126 #define FTRACE_EVENTS() VMLINUX_SYMBOL(__start_ftrace_events) = .;      \
127                         *(_ftrace_events)                               \
128                         VMLINUX_SYMBOL(__stop_ftrace_events) = .;
129 #else
130 #define FTRACE_EVENTS()
131 #endif
132
133 #ifdef CONFIG_TRACING
134 #define TRACE_PRINTKS() VMLINUX_SYMBOL(__start___trace_bprintk_fmt) = .;      \
135                          *(__trace_printk_fmt) /* Trace_printk fmt' pointer */ \
136                          VMLINUX_SYMBOL(__stop___trace_bprintk_fmt) = .;
137 #else
138 #define TRACE_PRINTKS()
139 #endif
140
141 #ifdef CONFIG_FTRACE_SYSCALLS
142 #define TRACE_SYSCALLS() VMLINUX_SYMBOL(__start_syscalls_metadata) = .; \
143                          *(__syscalls_metadata)                         \
144                          VMLINUX_SYMBOL(__stop_syscalls_metadata) = .;
145 #else
146 #define TRACE_SYSCALLS()
147 #endif
148
149 /* .data section */
150 #define DATA_DATA                                                       \
151         *(.data)                                                        \
152         *(.ref.data)                                                    \
153         DEV_KEEP(init.data)                                             \
154         DEV_KEEP(exit.data)                                             \
155         CPU_KEEP(init.data)                                             \
156         CPU_KEEP(exit.data)                                             \
157         MEM_KEEP(init.data)                                             \
158         MEM_KEEP(exit.data)                                             \
159         . = ALIGN(8);                                                   \
160         VMLINUX_SYMBOL(__start___markers) = .;                          \
161         *(__markers)                                                    \
162         VMLINUX_SYMBOL(__stop___markers) = .;                           \
163         . = ALIGN(32);                                                  \
164         VMLINUX_SYMBOL(__start___tracepoints) = .;                      \
165         *(__tracepoints)                                                \
166         VMLINUX_SYMBOL(__stop___tracepoints) = .;                       \
167         /* implement dynamic printk debug */                            \
168         . = ALIGN(8);                                                   \
169         VMLINUX_SYMBOL(__start___verbose) = .;                          \
170         *(__verbose)                                                    \
171         VMLINUX_SYMBOL(__stop___verbose) = .;                           \
172         LIKELY_PROFILE()                                                \
173         BRANCH_PROFILE()                                                \
174         TRACE_PRINTKS()                                                 \
175                                                                         \
176         STRUCT_ALIGN();                                                 \
177         FTRACE_EVENTS()                                                 \
178                                                                         \
179         STRUCT_ALIGN();                                                 \
180         TRACE_SYSCALLS()
181
182 /*
183  * Data section helpers
184  */
185 #define NOSAVE_DATA                                                     \
186         . = ALIGN(PAGE_SIZE);                                           \
187         VMLINUX_SYMBOL(__nosave_begin) = .;                             \
188         *(.data..nosave)                                                \
189         . = ALIGN(PAGE_SIZE);                                           \
190         VMLINUX_SYMBOL(__nosave_end) = .;
191
192 #define PAGE_ALIGNED_DATA(page_align)                                   \
193         . = ALIGN(page_align);                                          \
194         *(.data..page_aligned)
195
196 #define READ_MOSTLY_DATA(align)                                         \
197         . = ALIGN(align);                                               \
198         *(.data..read_mostly)
199
200 #define CACHELINE_ALIGNED_DATA(align)                                   \
201         . = ALIGN(align);                                               \
202         *(.data..cacheline_aligned)
203
204 #define INIT_TASK_DATA(align)                                           \
205         . = ALIGN(align);                                               \
206         *(.data..init_task)
207
208 /*
209  * Read only Data
210  */
211 #define RO_DATA_SECTION(align)                                          \
212         . = ALIGN((align));                                             \
213         .rodata           : AT(ADDR(.rodata) - LOAD_OFFSET) {           \
214                 VMLINUX_SYMBOL(__start_rodata) = .;                     \
215                 *(.rodata) *(.rodata.*)                                 \
216                 *(__vermagic)           /* Kernel version magic */      \
217                 *(__markers_strings)    /* Markers: strings */          \
218                 *(__tracepoints_strings)/* Tracepoints: strings */      \
219         }                                                               \
220                                                                         \
221         .rodata1          : AT(ADDR(.rodata1) - LOAD_OFFSET) {          \
222                 *(.rodata1)                                             \
223         }                                                               \
224                                                                         \
225         BUG_TABLE                                                       \
226                                                                         \
227         /* PCI quirks */                                                \
228         .pci_fixup        : AT(ADDR(.pci_fixup) - LOAD_OFFSET) {        \
229                 VMLINUX_SYMBOL(__start_pci_fixups_early) = .;           \
230                 *(.pci_fixup_early)                                     \
231                 VMLINUX_SYMBOL(__end_pci_fixups_early) = .;             \
232                 VMLINUX_SYMBOL(__start_pci_fixups_header) = .;          \
233                 *(.pci_fixup_header)                                    \
234                 VMLINUX_SYMBOL(__end_pci_fixups_header) = .;            \
235                 VMLINUX_SYMBOL(__start_pci_fixups_final) = .;           \
236                 *(.pci_fixup_final)                                     \
237                 VMLINUX_SYMBOL(__end_pci_fixups_final) = .;             \
238                 VMLINUX_SYMBOL(__start_pci_fixups_enable) = .;          \
239                 *(.pci_fixup_enable)                                    \
240                 VMLINUX_SYMBOL(__end_pci_fixups_enable) = .;            \
241                 VMLINUX_SYMBOL(__start_pci_fixups_resume) = .;          \
242                 *(.pci_fixup_resume)                                    \
243                 VMLINUX_SYMBOL(__end_pci_fixups_resume) = .;            \
244                 VMLINUX_SYMBOL(__start_pci_fixups_resume_early) = .;    \
245                 *(.pci_fixup_resume_early)                              \
246                 VMLINUX_SYMBOL(__end_pci_fixups_resume_early) = .;      \
247                 VMLINUX_SYMBOL(__start_pci_fixups_suspend) = .;         \
248                 *(.pci_fixup_suspend)                                   \
249                 VMLINUX_SYMBOL(__end_pci_fixups_suspend) = .;           \
250         }                                                               \
251                                                                         \
252         /* Built-in firmware blobs */                                   \
253         .builtin_fw        : AT(ADDR(.builtin_fw) - LOAD_OFFSET) {      \
254                 VMLINUX_SYMBOL(__start_builtin_fw) = .;                 \
255                 *(.builtin_fw)                                          \
256                 VMLINUX_SYMBOL(__end_builtin_fw) = .;                   \
257         }                                                               \
258                                                                         \
259         /* RapidIO route ops */                                         \
260         .rio_ops        : AT(ADDR(.rio_ops) - LOAD_OFFSET) {            \
261                 VMLINUX_SYMBOL(__start_rio_switch_ops) = .;             \
262                 *(.rio_switch_ops)                                      \
263                 VMLINUX_SYMBOL(__end_rio_switch_ops) = .;               \
264         }                                                               \
265                                                                         \
266         TRACEDATA                                                       \
267                                                                         \
268         /* Kernel symbol table: Normal symbols */                       \
269         __ksymtab         : AT(ADDR(__ksymtab) - LOAD_OFFSET) {         \
270                 VMLINUX_SYMBOL(__start___ksymtab) = .;                  \
271                 *(__ksymtab)                                            \
272                 VMLINUX_SYMBOL(__stop___ksymtab) = .;                   \
273         }                                                               \
274                                                                         \
275         /* Kernel symbol table: GPL-only symbols */                     \
276         __ksymtab_gpl     : AT(ADDR(__ksymtab_gpl) - LOAD_OFFSET) {     \
277                 VMLINUX_SYMBOL(__start___ksymtab_gpl) = .;              \
278                 *(__ksymtab_gpl)                                        \
279                 VMLINUX_SYMBOL(__stop___ksymtab_gpl) = .;               \
280         }                                                               \
281                                                                         \
282         /* Kernel symbol table: Normal unused symbols */                \
283         __ksymtab_unused  : AT(ADDR(__ksymtab_unused) - LOAD_OFFSET) {  \
284                 VMLINUX_SYMBOL(__start___ksymtab_unused) = .;           \
285                 *(__ksymtab_unused)                                     \
286                 VMLINUX_SYMBOL(__stop___ksymtab_unused) = .;            \
287         }                                                               \
288                                                                         \
289         /* Kernel symbol table: GPL-only unused symbols */              \
290         __ksymtab_unused_gpl : AT(ADDR(__ksymtab_unused_gpl) - LOAD_OFFSET) { \
291                 VMLINUX_SYMBOL(__start___ksymtab_unused_gpl) = .;       \
292                 *(__ksymtab_unused_gpl)                                 \
293                 VMLINUX_SYMBOL(__stop___ksymtab_unused_gpl) = .;        \
294         }                                                               \
295                                                                         \
296         /* Kernel symbol table: GPL-future-only symbols */              \
297         __ksymtab_gpl_future : AT(ADDR(__ksymtab_gpl_future) - LOAD_OFFSET) { \
298                 VMLINUX_SYMBOL(__start___ksymtab_gpl_future) = .;       \
299                 *(__ksymtab_gpl_future)                                 \
300                 VMLINUX_SYMBOL(__stop___ksymtab_gpl_future) = .;        \
301         }                                                               \
302                                                                         \
303         /* Kernel symbol table: Normal symbols */                       \
304         __kcrctab         : AT(ADDR(__kcrctab) - LOAD_OFFSET) {         \
305                 VMLINUX_SYMBOL(__start___kcrctab) = .;                  \
306                 *(__kcrctab)                                            \
307                 VMLINUX_SYMBOL(__stop___kcrctab) = .;                   \
308         }                                                               \
309                                                                         \
310         /* Kernel symbol table: GPL-only symbols */                     \
311         __kcrctab_gpl     : AT(ADDR(__kcrctab_gpl) - LOAD_OFFSET) {     \
312                 VMLINUX_SYMBOL(__start___kcrctab_gpl) = .;              \
313                 *(__kcrctab_gpl)                                        \
314                 VMLINUX_SYMBOL(__stop___kcrctab_gpl) = .;               \
315         }                                                               \
316                                                                         \
317         /* Kernel symbol table: Normal unused symbols */                \
318         __kcrctab_unused  : AT(ADDR(__kcrctab_unused) - LOAD_OFFSET) {  \
319                 VMLINUX_SYMBOL(__start___kcrctab_unused) = .;           \
320                 *(__kcrctab_unused)                                     \
321                 VMLINUX_SYMBOL(__stop___kcrctab_unused) = .;            \
322         }                                                               \
323                                                                         \
324         /* Kernel symbol table: GPL-only unused symbols */              \
325         __kcrctab_unused_gpl : AT(ADDR(__kcrctab_unused_gpl) - LOAD_OFFSET) { \
326                 VMLINUX_SYMBOL(__start___kcrctab_unused_gpl) = .;       \
327                 *(__kcrctab_unused_gpl)                                 \
328                 VMLINUX_SYMBOL(__stop___kcrctab_unused_gpl) = .;        \
329         }                                                               \
330                                                                         \
331         /* Kernel symbol table: GPL-future-only symbols */              \
332         __kcrctab_gpl_future : AT(ADDR(__kcrctab_gpl_future) - LOAD_OFFSET) { \
333                 VMLINUX_SYMBOL(__start___kcrctab_gpl_future) = .;       \
334                 *(__kcrctab_gpl_future)                                 \
335                 VMLINUX_SYMBOL(__stop___kcrctab_gpl_future) = .;        \
336         }                                                               \
337                                                                         \
338         /* Kernel symbol table: strings */                              \
339         __ksymtab_strings : AT(ADDR(__ksymtab_strings) - LOAD_OFFSET) { \
340                 *(__ksymtab_strings)                                    \
341         }                                                               \
342                                                                         \
343         /* __*init sections */                                          \
344         __init_rodata : AT(ADDR(__init_rodata) - LOAD_OFFSET) {         \
345                 *(.ref.rodata)                                          \
346                 DEV_KEEP(init.rodata)                                   \
347                 DEV_KEEP(exit.rodata)                                   \
348                 CPU_KEEP(init.rodata)                                   \
349                 CPU_KEEP(exit.rodata)                                   \
350                 MEM_KEEP(init.rodata)                                   \
351                 MEM_KEEP(exit.rodata)                                   \
352         }                                                               \
353                                                                         \
354         /* Built-in module parameters. */                               \
355         __param : AT(ADDR(__param) - LOAD_OFFSET) {                     \
356                 VMLINUX_SYMBOL(__start___param) = .;                    \
357                 *(__param)                                              \
358                 VMLINUX_SYMBOL(__stop___param) = .;                     \
359                 . = ALIGN((align));                                     \
360                 VMLINUX_SYMBOL(__end_rodata) = .;                       \
361         }                                                               \
362         . = ALIGN((align));
363
364 /* RODATA & RO_DATA provided for backward compatibility.
365  * All archs are supposed to use RO_DATA() */
366 #define RODATA          RO_DATA_SECTION(4096)
367 #define RO_DATA(align)  RO_DATA_SECTION(align)
368
369 #define SECURITY_INIT                                                   \
370         .security_initcall.init : AT(ADDR(.security_initcall.init) - LOAD_OFFSET) { \
371                 VMLINUX_SYMBOL(__security_initcall_start) = .;          \
372                 *(.security_initcall.init)                              \
373                 VMLINUX_SYMBOL(__security_initcall_end) = .;            \
374         }
375
376 /* .text section. Map to function alignment to avoid address changes
377  * during second ld run in second ld pass when generating System.map */
378 #define TEXT_TEXT                                                       \
379                 ALIGN_FUNCTION();                                       \
380                 *(.text.hot)                                            \
381                 *(.text)                                                \
382                 *(.ref.text)                                            \
383         DEV_KEEP(init.text)                                             \
384         DEV_KEEP(exit.text)                                             \
385         CPU_KEEP(init.text)                                             \
386         CPU_KEEP(exit.text)                                             \
387         MEM_KEEP(init.text)                                             \
388         MEM_KEEP(exit.text)                                             \
389                 *(.text.unlikely)
390
391
392 /* sched.text is aling to function alignment to secure we have same
393  * address even at second ld pass when generating System.map */
394 #define SCHED_TEXT                                                      \
395                 ALIGN_FUNCTION();                                       \
396                 VMLINUX_SYMBOL(__sched_text_start) = .;                 \
397                 *(.sched.text)                                          \
398                 VMLINUX_SYMBOL(__sched_text_end) = .;
399
400 /* spinlock.text is aling to function alignment to secure we have same
401  * address even at second ld pass when generating System.map */
402 #define LOCK_TEXT                                                       \
403                 ALIGN_FUNCTION();                                       \
404                 VMLINUX_SYMBOL(__lock_text_start) = .;                  \
405                 *(.spinlock.text)                                       \
406                 VMLINUX_SYMBOL(__lock_text_end) = .;
407
408 #define KPROBES_TEXT                                                    \
409                 ALIGN_FUNCTION();                                       \
410                 VMLINUX_SYMBOL(__kprobes_text_start) = .;               \
411                 *(.kprobes.text)                                        \
412                 VMLINUX_SYMBOL(__kprobes_text_end) = .;
413
414 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
415 #define IRQENTRY_TEXT                                                   \
416                 ALIGN_FUNCTION();                                       \
417                 VMLINUX_SYMBOL(__irqentry_text_start) = .;              \
418                 *(.irqentry.text)                                       \
419                 VMLINUX_SYMBOL(__irqentry_text_end) = .;
420 #else
421 #define IRQENTRY_TEXT
422 #endif
423
424 /* Section used for early init (in .S files) */
425 #define HEAD_TEXT  *(.head.text)
426
427 #define HEAD_TEXT_SECTION                                                       \
428         .head.text : AT(ADDR(.head.text) - LOAD_OFFSET) {               \
429                 HEAD_TEXT                                               \
430         }
431
432 /*
433  * Exception table
434  */
435 #define EXCEPTION_TABLE(align)                                          \
436         . = ALIGN(align);                                               \
437         __ex_table : AT(ADDR(__ex_table) - LOAD_OFFSET) {               \
438                 VMLINUX_SYMBOL(__start___ex_table) = .;                 \
439                 *(__ex_table)                                           \
440                 VMLINUX_SYMBOL(__stop___ex_table) = .;                  \
441         }
442
443 /*
444  * Init task
445  */
446 #define INIT_TASK_DATA_SECTION(align)                                   \
447         . = ALIGN(align);                                               \
448         .data..init_task :  AT(ADDR(.data..init_task) - LOAD_OFFSET) {  \
449                 INIT_TASK_DATA(align)                                   \
450         }
451
452 #ifdef CONFIG_CONSTRUCTORS
453 #define KERNEL_CTORS()  . = ALIGN(8);                      \
454                         VMLINUX_SYMBOL(__ctors_start) = .; \
455                         *(.ctors)                          \
456                         VMLINUX_SYMBOL(__ctors_end) = .;
457 #else
458 #define KERNEL_CTORS()
459 #endif
460
461 /* init and exit section handling */
462 #define INIT_DATA                                                       \
463         *(.init.data)                                                   \
464         DEV_DISCARD(init.data)                                          \
465         CPU_DISCARD(init.data)                                          \
466         MEM_DISCARD(init.data)                                          \
467         KERNEL_CTORS()                                                  \
468         *(.init.rodata)                                                 \
469         MCOUNT_REC()                                                    \
470         DEV_DISCARD(init.rodata)                                        \
471         CPU_DISCARD(init.rodata)                                        \
472         MEM_DISCARD(init.rodata)
473
474 #define INIT_TEXT                                                       \
475         *(.init.text)                                                   \
476         DEV_DISCARD(init.text)                                          \
477         CPU_DISCARD(init.text)                                          \
478         MEM_DISCARD(init.text)
479
480 #define EXIT_DATA                                                       \
481         *(.exit.data)                                                   \
482         DEV_DISCARD(exit.data)                                          \
483         DEV_DISCARD(exit.rodata)                                        \
484         CPU_DISCARD(exit.data)                                          \
485         CPU_DISCARD(exit.rodata)                                        \
486         MEM_DISCARD(exit.data)                                          \
487         MEM_DISCARD(exit.rodata)
488
489 #define EXIT_TEXT                                                       \
490         *(.exit.text)                                                   \
491         DEV_DISCARD(exit.text)                                          \
492         CPU_DISCARD(exit.text)                                          \
493         MEM_DISCARD(exit.text)
494
495 #define EXIT_CALL                                                       \
496         *(.exitcall.exit)
497
498 /*
499  * bss (Block Started by Symbol) - uninitialized data
500  * zeroed during startup
501  */
502 #define SBSS(sbss_align)                                                \
503         . = ALIGN(sbss_align);                                          \
504         .sbss : AT(ADDR(.sbss) - LOAD_OFFSET) {                         \
505                 *(.sbss)                                                \
506                 *(.scommon)                                             \
507         }
508
509 #define BSS(bss_align)                                                  \
510         . = ALIGN(bss_align);                                           \
511         .bss : AT(ADDR(.bss) - LOAD_OFFSET) {                           \
512                 *(.bss..page_aligned)                                   \
513                 *(.dynbss)                                              \
514                 *(.bss)                                                 \
515                 *(COMMON)                                               \
516         }
517
518 /*
519  * DWARF debug sections.
520  * Symbols in the DWARF debugging sections are relative to
521  * the beginning of the section so we begin them at 0.
522  */
523 #define DWARF_DEBUG                                                     \
524                 /* DWARF 1 */                                           \
525                 .debug          0 : { *(.debug) }                       \
526                 .line           0 : { *(.line) }                        \
527                 /* GNU DWARF 1 extensions */                            \
528                 .debug_srcinfo  0 : { *(.debug_srcinfo) }               \
529                 .debug_sfnames  0 : { *(.debug_sfnames) }               \
530                 /* DWARF 1.1 and DWARF 2 */                             \
531                 .debug_aranges  0 : { *(.debug_aranges) }               \
532                 .debug_pubnames 0 : { *(.debug_pubnames) }              \
533                 /* DWARF 2 */                                           \
534                 .debug_info     0 : { *(.debug_info                     \
535                                 .gnu.linkonce.wi.*) }                   \
536                 .debug_abbrev   0 : { *(.debug_abbrev) }                \
537                 .debug_line     0 : { *(.debug_line) }                  \
538                 .debug_frame    0 : { *(.debug_frame) }                 \
539                 .debug_str      0 : { *(.debug_str) }                   \
540                 .debug_loc      0 : { *(.debug_loc) }                   \
541                 .debug_macinfo  0 : { *(.debug_macinfo) }               \
542                 /* SGI/MIPS DWARF 2 extensions */                       \
543                 .debug_weaknames 0 : { *(.debug_weaknames) }            \
544                 .debug_funcnames 0 : { *(.debug_funcnames) }            \
545                 .debug_typenames 0 : { *(.debug_typenames) }            \
546                 .debug_varnames  0 : { *(.debug_varnames) }             \
547
548                 /* Stabs debugging sections.  */
549 #define STABS_DEBUG                                                     \
550                 .stab 0 : { *(.stab) }                                  \
551                 .stabstr 0 : { *(.stabstr) }                            \
552                 .stab.excl 0 : { *(.stab.excl) }                        \
553                 .stab.exclstr 0 : { *(.stab.exclstr) }                  \
554                 .stab.index 0 : { *(.stab.index) }                      \
555                 .stab.indexstr 0 : { *(.stab.indexstr) }                \
556                 .comment 0 : { *(.comment) }
557
558 #ifdef CONFIG_GENERIC_BUG
559 #define BUG_TABLE                                                       \
560         . = ALIGN(8);                                                   \
561         __bug_table : AT(ADDR(__bug_table) - LOAD_OFFSET) {             \
562                 VMLINUX_SYMBOL(__start___bug_table) = .;                \
563                 *(__bug_table)                                          \
564                 VMLINUX_SYMBOL(__stop___bug_table) = .;                 \
565         }
566 #else
567 #define BUG_TABLE
568 #endif
569
570 #ifdef CONFIG_PM_TRACE
571 #define TRACEDATA                                                       \
572         . = ALIGN(4);                                                   \
573         .tracedata : AT(ADDR(.tracedata) - LOAD_OFFSET) {               \
574                 VMLINUX_SYMBOL(__tracedata_start) = .;                  \
575                 *(.tracedata)                                           \
576                 VMLINUX_SYMBOL(__tracedata_end) = .;                    \
577         }
578 #else
579 #define TRACEDATA
580 #endif
581
582 #define NOTES                                                           \
583         .notes : AT(ADDR(.notes) - LOAD_OFFSET) {                       \
584                 VMLINUX_SYMBOL(__start_notes) = .;                      \
585                 *(.note.*)                                              \
586                 VMLINUX_SYMBOL(__stop_notes) = .;                       \
587         }
588
589 #define INIT_SETUP(initsetup_align)                                     \
590                 . = ALIGN(initsetup_align);                             \
591                 VMLINUX_SYMBOL(__setup_start) = .;                      \
592                 *(.init.setup)                                          \
593                 VMLINUX_SYMBOL(__setup_end) = .;
594
595 #define INITCALLS                                                       \
596         *(.initcallearly.init)                                          \
597         VMLINUX_SYMBOL(__early_initcall_end) = .;                       \
598         *(.initcall0.init)                                              \
599         *(.initcall0s.init)                                             \
600         *(.initcall1.init)                                              \
601         *(.initcall1s.init)                                             \
602         *(.initcall2.init)                                              \
603         *(.initcall2s.init)                                             \
604         *(.initcall3.init)                                              \
605         *(.initcall3s.init)                                             \
606         *(.initcall4.init)                                              \
607         *(.initcall4s.init)                                             \
608         *(.initcall5.init)                                              \
609         *(.initcall5s.init)                                             \
610         *(.initcallrootfs.init)                                         \
611         *(.initcall6.init)                                              \
612         *(.initcall6s.init)                                             \
613         *(.initcall7.init)                                              \
614         *(.initcall7s.init)
615
616 #define INIT_CALLS                                                      \
617                 VMLINUX_SYMBOL(__initcall_start) = .;                   \
618                 INITCALLS                                               \
619                 VMLINUX_SYMBOL(__initcall_end) = .;
620
621 #define CON_INITCALL                                                    \
622                 VMLINUX_SYMBOL(__con_initcall_start) = .;               \
623                 *(.con_initcall.init)                                   \
624                 VMLINUX_SYMBOL(__con_initcall_end) = .;
625
626 #define SECURITY_INITCALL                                               \
627                 VMLINUX_SYMBOL(__security_initcall_start) = .;          \
628                 *(.security_initcall.init)                              \
629                 VMLINUX_SYMBOL(__security_initcall_end) = .;
630
631 #ifdef CONFIG_BLK_DEV_INITRD
632 #define INIT_RAM_FS                                                     \
633         . = ALIGN(PAGE_SIZE);                                           \
634         VMLINUX_SYMBOL(__initramfs_start) = .;                          \
635         *(.init.ramfs)                                                  \
636         VMLINUX_SYMBOL(__initramfs_end) = .;
637 #else
638 #define INIT_RAM_FS
639 #endif
640
641 /*
642  * Default discarded sections.
643  *
644  * Some archs want to discard exit text/data at runtime rather than
645  * link time due to cross-section references such as alt instructions,
646  * bug table, eh_frame, etc.  DISCARDS must be the last of output
647  * section definitions so that such archs put those in earlier section
648  * definitions.
649  */
650 #define DISCARDS                                                        \
651         /DISCARD/ : {                                                   \
652         EXIT_TEXT                                                       \
653         EXIT_DATA                                                       \
654         EXIT_CALL                                                       \
655         *(.discard)                                                     \
656         }
657
658 /**
659  * PERCPU_VADDR - define output section for percpu area
660  * @vaddr: explicit base address (optional)
661  * @phdr: destination PHDR (optional)
662  *
663  * Macro which expands to output section for percpu area.  If @vaddr
664  * is not blank, it specifies explicit base address and all percpu
665  * symbols will be offset from the given address.  If blank, @vaddr
666  * always equals @laddr + LOAD_OFFSET.
667  *
668  * @phdr defines the output PHDR to use if not blank.  Be warned that
669  * output PHDR is sticky.  If @phdr is specified, the next output
670  * section in the linker script will go there too.  @phdr should have
671  * a leading colon.
672  *
673  * Note that this macros defines __per_cpu_load as an absolute symbol.
674  * If there is no need to put the percpu section at a predetermined
675  * address, use PERCPU().
676  */
677 #define PERCPU_VADDR(vaddr, phdr)                                       \
678         VMLINUX_SYMBOL(__per_cpu_load) = .;                             \
679         .data..percpu vaddr : AT(VMLINUX_SYMBOL(__per_cpu_load)         \
680                                 - LOAD_OFFSET) {                        \
681                 VMLINUX_SYMBOL(__per_cpu_start) = .;                    \
682                 *(.data..percpu..first)                                 \
683                 *(.data..percpu..page_aligned)                          \
684                 *(.data..percpu)                                        \
685                 *(.data..percpu..shared_aligned)                        \
686                 VMLINUX_SYMBOL(__per_cpu_end) = .;                      \
687         } phdr                                                          \
688         . = VMLINUX_SYMBOL(__per_cpu_load) + SIZEOF(.data..percpu);
689
690 /**
691  * PERCPU - define output section for percpu area, simple version
692  * @align: required alignment
693  *
694  * Align to @align and outputs output section for percpu area.  This
695  * macro doesn't maniuplate @vaddr or @phdr and __per_cpu_load and
696  * __per_cpu_start will be identical.
697  *
698  * This macro is equivalent to ALIGN(align); PERCPU_VADDR( , ) except
699  * that __per_cpu_load is defined as a relative symbol against
700  * .data..percpu which is required for relocatable x86_32
701  * configuration.
702  */
703 #define PERCPU(align)                                                   \
704         . = ALIGN(align);                                               \
705         .data..percpu   : AT(ADDR(.data..percpu) - LOAD_OFFSET) {       \
706                 VMLINUX_SYMBOL(__per_cpu_load) = .;                     \
707                 VMLINUX_SYMBOL(__per_cpu_start) = .;                    \
708                 *(.data..percpu..first)                                 \
709                 *(.data..percpu..page_aligned)                          \
710                 *(.data..percpu)                                        \
711                 *(.data..percpu..shared_aligned)                        \
712                 VMLINUX_SYMBOL(__per_cpu_end) = .;                      \
713         }
714
715
716 /*
717  * Definition of the high level *_SECTION macros
718  * They will fit only a subset of the architectures
719  */
720
721
722 /*
723  * Writeable data.
724  * All sections are combined in a single .data section.
725  * The sections following CONSTRUCTORS are arranged so their
726  * typical alignment matches.
727  * A cacheline is typical/always less than a PAGE_SIZE so
728  * the sections that has this restriction (or similar)
729  * is located before the ones requiring PAGE_SIZE alignment.
730  * NOSAVE_DATA starts and ends with a PAGE_SIZE alignment which
731  * matches the requirment of PAGE_ALIGNED_DATA.
732  *
733  * use 0 as page_align if page_aligned data is not used */
734 #define RW_DATA_SECTION(cacheline, pagealigned, inittask)               \
735         . = ALIGN(PAGE_SIZE);                                           \
736         .data : AT(ADDR(.data) - LOAD_OFFSET) {                         \
737                 INIT_TASK_DATA(inittask)                                \
738                 NOSAVE_DATA                                             \
739                 PAGE_ALIGNED_DATA(pagealigned)                          \
740                 CACHELINE_ALIGNED_DATA(cacheline)                       \
741                 READ_MOSTLY_DATA(cacheline)                             \
742                 DATA_DATA                                               \
743                 CONSTRUCTORS                                            \
744         }
745
746 #define INIT_TEXT_SECTION(inittext_align)                               \
747         . = ALIGN(inittext_align);                                      \
748         .init.text : AT(ADDR(.init.text) - LOAD_OFFSET) {               \
749                 VMLINUX_SYMBOL(_sinittext) = .;                         \
750                 INIT_TEXT                                               \
751                 VMLINUX_SYMBOL(_einittext) = .;                         \
752         }
753
754 #define INIT_DATA_SECTION(initsetup_align)                              \
755         .init.data : AT(ADDR(.init.data) - LOAD_OFFSET) {               \
756                 INIT_DATA                                               \
757                 INIT_SETUP(initsetup_align)                             \
758                 INIT_CALLS                                              \
759                 CON_INITCALL                                            \
760                 SECURITY_INITCALL                                       \
761                 INIT_RAM_FS                                             \
762         }
763
764 #define BSS_SECTION(sbss_align, bss_align, stop_align)                  \
765         . = ALIGN(sbss_align);                                          \
766         VMLINUX_SYMBOL(__bss_start) = .;                                \
767         SBSS(sbss_align)                                                \
768         BSS(bss_align)                                                  \
769         . = ALIGN(stop_align);                                          \
770         VMLINUX_SYMBOL(__bss_stop) = .;