arch/x86_64/kernel/head.S

   1 /*
   2  *  linux/arch/x86_64/kernel/head.S -- start in 32bit and switch to 64bit
   3  *
   4  *  Copyright (C) 2000 Andrea Arcangeli <andrea@suse.de> SuSE
   5  *  Copyright (C) 2000 Pavel Machek <pavel@suse.cz>
   6  *  Copyright (C) 2000 Karsten Keil <kkeil@suse.de>
   7  *  Copyright (C) 2001,2002 Andi Kleen <ak@suse.de>
   8  */
   9
  10
  11 #include <linux/linkage.h>
  12 #include <linux/threads.h>
  13 #include <linux/init.h>
  14 #include <asm/desc.h>
  15 #include <asm/segment.h>
  16 #include <asm/page.h>
  17 #include <asm/msr.h>
  18 #include <asm/cache.h>
  19
  20 /* we are not able to switch in one step to the final KERNEL ADRESS SPACE
  21  * because we need identity-mapped pages on setup so define __START_KERNEL to
  22  * 0x100000 for this stage
  23  *
  24  */
  25
  26         .text
  27         .section .bootstrap.text
  28         .code32
  29         .globl startup_32
  30 /* %bx:  1 if coming from smp trampoline on secondary cpu */
  31 startup_32:
  32
  33         /*
  34          * At this point the CPU runs in 32bit protected mode (CS.D = 1) with
  35          * paging disabled and the point of this file is to switch to 64bit
  36          * long mode with a kernel mapping for kerneland to jump into the
  37          * kernel virtual addresses.
  38          * There is no stack until we set one up.
  39          */
  40
  41         /* Initialize the %ds segment register */
  42         movl $__KERNEL_DS,%eax
  43         movl %eax,%ds
  44
  45         /* Load new GDT with the 64bit segments using 32bit descriptor */
  46         lgdt    pGDT32 - __START_KERNEL_map
  47
  48         /* If the CPU doesn't support CPUID this will double fault.
  49          * Unfortunately it is hard to check for CPUID without a stack.
  50          */
  51
  52         /* Check if extended functions are implemented */
  53         movl    $0x80000000, %eax
  54         cpuid
  55         cmpl    $0x80000000, %eax
  56         jbe     no_long_mode
  57         /* Check if long mode is implemented */
  58         mov     $0x80000001, %eax
  59         cpuid
  60         btl     $29, %edx
  61         jnc     no_long_mode
  62
  63         /*
  64          * Prepare for entering 64bits mode
  65          */
  66
  67         /* Enable PAE mode */
  68         xorl    %eax, %eax
  69         btsl    $5, %eax
  70         movl    %eax, %cr4
  71
  72         /* Setup early boot stage 4 level pagetables */
  73         movl    $(boot_level4_pgt - __START_KERNEL_map), %eax
  74         movl    %eax, %cr3
  75
  76         /* Setup EFER (Extended Feature Enable Register) */
  77         movl    $MSR_EFER, %ecx
  78         rdmsr
  79
  80         /* Enable Long Mode */
  81         btsl    $_EFER_LME, %eax
  82
  83         /* Make changes effective */
  84         wrmsr
  85
  86         xorl    %eax, %eax
  87         btsl    $31, %eax                       /* Enable paging and in turn activate Long Mode */
  88         btsl    $0, %eax                        /* Enable protected mode */
  89         /* Make changes effective */
  90         movl    %eax, %cr0
  91         /*
  92          * At this point we're in long mode but in 32bit compatibility mode
  93          * with EFER.LME = 1, CS.L = 0, CS.D = 1 (and in turn
  94          * EFER.LMA = 1). Now we want to jump in 64bit mode, to do that we use
  95          * the new gdt/idt that has __KERNEL_CS with CS.L = 1.
  96          */
  97         ljmp    $__KERNEL_CS, $(startup_64 - __START_KERNEL_map)
  98
  99         .code64
 100         .org 0x100
 101         .globl startup_64
 102 startup_64:
 103         /* We come here either from startup_32
 104          * or directly from a 64bit bootloader.
 105          * Since we may have come directly from a bootloader we
 106          * reload the page tables here.
 107          */
 108
 109         /* Enable PAE mode and PGE */
 110         xorq    %rax, %rax
 111         btsq    $5, %rax
 112         btsq    $7, %rax
 113         movq    %rax, %cr4
 114
 115         /* Setup early boot stage 4 level pagetables. */
 116         movq    $(boot_level4_pgt - __START_KERNEL_map), %rax
 117         movq    %rax, %cr3
 118
 119         /* Check if nx is implemented */
 120         movl    $0x80000001, %eax
 121         cpuid
 122         movl    %edx,%edi
 123
 124         /* Setup EFER (Extended Feature Enable Register) */
 125         movl    $MSR_EFER, %ecx
 126         rdmsr
 127
 128         /* Enable System Call */
 129         btsl    $_EFER_SCE, %eax
 130
 131         /* No Execute supported? */
 132         btl     $20,%edi
 133         jnc     1f
 134         btsl    $_EFER_NX, %eax
 135 1:
 136         /* Make changes effective */
 137         wrmsr
 138
 139         /* Setup cr0 */
 140 #define CR0_PM                          1               /* protected mode */
 141 #define CR0_MP                          (1<<1)
 142 #define CR0_ET                          (1<<4)
 143 #define CR0_NE                          (1<<5)
 144 #define CR0_WP                          (1<<16)
 145 #define CR0_AM                          (1<<18)
 146 #define CR0_PAGING                      (1<<31)
 147         movl $CR0_PM|CR0_MP|CR0_ET|CR0_NE|CR0_WP|CR0_AM|CR0_PAGING,%eax
 148         /* Make changes effective */
 149         movq    %rax, %cr0
 150
 151         /* Setup a boot time stack */
 152         movq init_rsp(%rip),%rsp
 153
 154         /* zero EFLAGS after setting rsp */
 155         pushq $0
 156         popfq
 157
 158         /*
 159          * We must switch to a new descriptor in kernel space for the GDT
 160          * because soon the kernel won't have access anymore to the userspace
 161          * addresses where we're currently running on. We have to do that here
 162          * because in 32bit we couldn't load a 64bit linear address.
 163          */
 164         lgdt    cpu_gdt_descr
 165
 166         /* set up data segments. actually 0 would do too */
 167         movl $__KERNEL_DS,%eax
 168         movl %eax,%ds
 169         movl %eax,%ss
 170         movl %eax,%es
 171
 172         /*
 173          * We don't really need to load %fs or %gs, but load them anyway
 174          * to kill any stale realmode selectors.  This allows execution
 175          * under VT hardware.
 176          */
 177         movl %eax,%fs
 178         movl %eax,%gs
 179
 180         /*
 181          * Setup up a dummy PDA. this is just for some early bootup code
 182          * that does in_interrupt()
 183          */
 184         movl    $MSR_GS_BASE,%ecx
 185         movq    $empty_zero_page,%rax
 186         movq    %rax,%rdx
 187         shrq    $32,%rdx
 188         wrmsr
 189
 190         /* esi is pointer to real mode structure with interesting info.
 191            pass it to C */
 192         movl    %esi, %edi
 193
 194         /* Finally jump to run C code and to be on real kernel address
 195          * Since we are running on identity-mapped space we have to jump
 196          * to the full 64bit address, this is only possible as indirect
 197          * jump.  In addition we need to ensure %cs is set so we make this
 198          * a far return.
 199          */
 200         movq    initial_code(%rip),%rax
 201         pushq   $0              # fake return address to stop unwinder
 202         pushq   $__KERNEL_CS    # set correct cs
 203         pushq   %rax            # target address in negative space
 204         lretq
 205
 206         /* SMP bootup changes these two */
 207         .align  8
 208         .globl  initial_code
 209 initial_code:
 210         .quad   x86_64_start_kernel
 211         .globl init_rsp
 212 init_rsp:
 213         .quad  init_thread_union+THREAD_SIZE-8
 214
 215 ENTRY(early_idt_handler)
 216         cmpl $2,early_recursion_flag(%rip)
 217         jz  1f
 218         incl early_recursion_flag(%rip)
 219         xorl %eax,%eax
 220         movq 8(%rsp),%rsi       # get rip
 221         movq (%rsp),%rdx
 222         movq %cr2,%rcx
 223         leaq early_idt_msg(%rip),%rdi
 224         call early_printk
 225         cmpl $2,early_recursion_flag(%rip)
 226         jz  1f
 227         call dump_stack
 228 #ifdef CONFIG_KALLSYMS
 229         leaq early_idt_ripmsg(%rip),%rdi
 230         movq 8(%rsp),%rsi       # get rip again
 231         call __print_symbol
 232 #endif
 233 1:      hlt
 234         jmp 1b
 235 early_recursion_flag:
 236         .long 0
 237
 238 early_idt_msg:
 239         .asciz "PANIC: early exception rip %lx error %lx cr2 %lx\n"
 240 early_idt_ripmsg:
 241         .asciz "RIP %s\n"
 242
 243 .code32
 244 ENTRY(no_long_mode)
 245         /* This isn't an x86-64 CPU so hang */
 246 1:
 247         jmp     1b
 248
 249 .org 0xf00
 250         .globl pGDT32
 251 pGDT32:
 252         .word   gdt_end-cpu_gdt_table-1
 253         .long   cpu_gdt_table-__START_KERNEL_map
 254
 255 .org 0xf10
 256 ljumpvector:
 257         .long   startup_64-__START_KERNEL_map
 258         .word   __KERNEL_CS
 259
 260 ENTRY(stext)
 261 ENTRY(_stext)
 262
 263         $page = 0
 264 #define NEXT_PAGE(name) \
 265         $page = $page + 1; \
 266         .org $page * 0x1000; \
 267         phys_/**/name = $page * 0x1000 + __PHYSICAL_START; \
 268 ENTRY(name)
 269
 270 NEXT_PAGE(init_level4_pgt)
 271         /* This gets initialized in x86_64_start_kernel */
 272         .fill   512,8,0
 273
 274 NEXT_PAGE(level3_ident_pgt)
 275         .quad   phys_level2_ident_pgt | 0x007
 276         .fill   511,8,0
 277
 278 NEXT_PAGE(level3_kernel_pgt)
 279         .fill   510,8,0
 280         /* (2^48-(2*1024*1024*1024)-((2^39)*511))/(2^30) = 510 */
 281         .quad   phys_level2_kernel_pgt | 0x007
 282         .fill   1,8,0
 283
 284 NEXT_PAGE(level2_ident_pgt)
 285         /* 40MB for bootup.     */
 286         i = 0
 287         .rept 20
 288         .quad   i << 21 | 0x083
 289         i = i + 1
 290         .endr
 291         /* Temporary mappings for the super early allocator in arch/x86_64/mm/init.c */
 292         .globl temp_boot_pmds
 293 temp_boot_pmds:
 294         .fill   492,8,0
 295
 296 NEXT_PAGE(level2_kernel_pgt)
 297         /* 40MB kernel mapping. The kernel code cannot be bigger than that.
 298            When you change this change KERNEL_TEXT_SIZE in page.h too. */
 299         /* (2^48-(2*1024*1024*1024)-((2^39)*511)-((2^30)*510)) = 0 */
 300         i = 0
 301         .rept 20
 302         .quad   i << 21 | 0x183
 303         i = i + 1
 304         .endr
 305         /* Module mapping starts here */
 306         .fill   492,8,0
 307
 308 NEXT_PAGE(level3_physmem_pgt)
 309         .quad   phys_level2_kernel_pgt | 0x007  /* so that __va works even before pagetable_init */
 310         .fill   511,8,0
 311
 312 #undef NEXT_PAGE
 313
 314         .data
 315
 316 #ifdef CONFIG_ACPI_SLEEP
 317         .align PAGE_SIZE
 318 ENTRY(wakeup_level4_pgt)
 319         .quad   phys_level3_ident_pgt | 0x007
 320         .fill   255,8,0
 321         .quad   phys_level3_physmem_pgt | 0x007
 322         .fill   254,8,0
 323         /* (2^48-(2*1024*1024*1024))/(2^39) = 511 */
 324         .quad   phys_level3_kernel_pgt | 0x007
 325 #endif
 326
 327 #ifndef CONFIG_HOTPLUG_CPU
 328         __INITDATA
 329 #endif
 330         /*
 331          * This default setting generates an ident mapping at address 0x100000
 332          * and a mapping for the kernel that precisely maps virtual address
 333          * 0xffffffff80000000 to physical address 0x000000. (always using
 334          * 2Mbyte large pages provided by PAE mode)
 335          */
 336         .align PAGE_SIZE
 337 ENTRY(boot_level4_pgt)
 338         .quad   phys_level3_ident_pgt | 0x007
 339         .fill   255,8,0
 340         .quad   phys_level3_physmem_pgt | 0x007
 341         .fill   254,8,0
 342         /* (2^48-(2*1024*1024*1024))/(2^39) = 511 */
 343         .quad   phys_level3_kernel_pgt | 0x007
 344
 345         .data
 346
 347         .align 16
 348         .globl cpu_gdt_descr
 349 cpu_gdt_descr:
 350         .word   gdt_end-cpu_gdt_table-1
 351 gdt:
 352         .quad   cpu_gdt_table
 353 #ifdef CONFIG_SMP
 354         .rept   NR_CPUS-1
 355         .word   0
 356         .quad   0
 357         .endr
 358 #endif
 359
 360 /* We need valid kernel segments for data and code in long mode too
 361  * IRET will check the segment types  kkeil 2000/10/28
 362  * Also sysret mandates a special GDT layout
 363  */
 364
 365         .section .data.page_aligned, "aw"
 366         .align PAGE_SIZE
 367
 368 /* The TLS descriptors are currently at a different place compared to i386.
 369    Hopefully nobody expects them at a fixed place (Wine?) */
 370
 371 ENTRY(cpu_gdt_table)
 372         .quad   0x0000000000000000      /* NULL descriptor */
 373         .quad   0x0                     /* unused */
 374         .quad   0x00af9a000000ffff      /* __KERNEL_CS */
 375         .quad   0x00cf92000000ffff      /* __KERNEL_DS */
 376         .quad   0x00cffa000000ffff      /* __USER32_CS */
 377         .quad   0x00cff2000000ffff      /* __USER_DS, __USER32_DS  */
 378         .quad   0x00affa000000ffff      /* __USER_CS */
 379         .quad   0x00cf9a000000ffff      /* __KERNEL32_CS */
 380         .quad   0,0                     /* TSS */
 381         .quad   0,0                     /* LDT */
 382         .quad   0,0,0                   /* three TLS descriptors */
 383         .quad   0x0000f40000000000      /* node/CPU stored in limit */
 384 gdt_end:
 385         /* asm/segment.h:GDT_ENTRIES must match this */
 386         /* This should be a multiple of the cache line size */
 387         /* GDTs of other CPUs are now dynamically allocated */
 388
 389         /* zero the remaining page */
 390         .fill PAGE_SIZE / 8 - GDT_ENTRIES,8,0
 391
 392         .section .bss, "aw", @nobits
 393         .align L1_CACHE_BYTES
 394 ENTRY(idt_table)
 395         .skip 256 * 16
 396
 397         .section .bss.page_aligned, "aw", @nobits
 398         .align PAGE_SIZE
 399 ENTRY(empty_zero_page)
 400         .skip PAGE_SIZE