arch/s390/kernel/vdso32/clock_gettime.S

   1 /*
   2  * Userland implementation of clock_gettime() for 32 bits processes in a
   3  * s390 kernel for use in the vDSO
   4  *
   5  *  Copyright IBM Corp. 2008
   6  *  Author(s): Martin Schwidefsky (schwidefsky@de.ibm.com)
   7  *
   8  * This program is free software; you can redistribute it and/or modify
   9  * it under the terms of the GNU General Public License (version 2 only)
  10  * as published by the Free Software Foundation.
  11  */
  12 #include <asm/vdso.h>
  13 #include <asm/asm-offsets.h>
  14 #include <asm/unistd.h>
  15
  16         .text
  17         .align 4
  18         .globl __kernel_clock_gettime
  19         .type  __kernel_clock_gettime,@function
  20 __kernel_clock_gettime:
  21         .cfi_startproc
  22         basr    %r5,0
  23 0:      al      %r5,21f-0b(%r5)                 /* get &_vdso_data */
  24         chi     %r2,__CLOCK_REALTIME
  25         je      10f
  26         chi     %r2,__CLOCK_MONOTONIC
  27         jne     19f
  28
  29         /* CLOCK_MONOTONIC */
  30         ltr     %r3,%r3
  31         jz      9f                              /* tp == NULL */
  32 1:      l       %r4,__VDSO_UPD_COUNT+4(%r5)     /* load update counter */
  33         tml     %r4,0x0001                      /* pending update ? loop */
  34         jnz     1b
  35         stck    24(%r15)                        /* Store TOD clock */
  36         lm      %r0,%r1,24(%r15)
  37         s       %r0,__VDSO_XTIME_STAMP(%r5)     /* TOD - cycle_last */
  38         sl      %r1,__VDSO_XTIME_STAMP+4(%r5)
  39         brc     3,2f
  40         ahi     %r0,-1
  41 2:      ms      %r0,__VDSO_TK_MULT(%r5)         /*  * tk->mult */
  42         lr      %r2,%r0
  43         l       %r0,__VDSO_TK_MULT(%r5)
  44         ltr     %r1,%r1
  45         mr      %r0,%r0
  46         jnm     3f
  47         a       %r0,__VDSO_TK_MULT(%r5)
  48 3:      alr     %r0,%r2
  49         al      %r0,__VDSO_XTIME_NSEC(%r5)      /*  + tk->xtime_nsec */
  50         al      %r1,__VDSO_XTIME_NSEC+4(%r5)
  51         brc     12,4f
  52         ahi     %r0,1
  53 4:      al      %r0,__VDSO_WTOM_NSEC(%r5)       /*  + wall_to_monotonic.nsec */
  54         al      %r1,__VDSO_WTOM_NSEC+4(%r5)
  55         brc     12,5f
  56         ahi     %r0,1
  57 5:      l       %r2,__VDSO_TK_SHIFT(%r5)        /* Timekeeper shift */
  58         srdl    %r0,0(%r2)                      /*  >> tk->shift */
  59         l       %r2,__VDSO_XTIME_SEC+4(%r5)
  60         al      %r2,__VDSO_WTOM_SEC+4(%r5)
  61         cl      %r4,__VDSO_UPD_COUNT+4(%r5)     /* check update counter */
  62         jne     1b
  63         basr    %r5,0
  64 6:      ltr     %r0,%r0
  65         jnz     7f
  66         cl      %r1,20f-6b(%r5)
  67         jl      8f
  68 7:      ahi     %r2,1
  69         sl      %r1,20f-6b(%r5)
  70         brc     3,6b
  71         ahi     %r0,-1
  72         j       6b
  73 8:      st      %r2,0(%r3)                      /* store tp->tv_sec */
  74         st      %r1,4(%r3)                      /* store tp->tv_nsec */
  75 9:      lhi     %r2,0
  76         br      %r14
  77
  78         /* CLOCK_REALTIME */
  79 10:     ltr     %r3,%r3                         /* tp == NULL */
  80         jz      18f
  81 11:     l       %r4,__VDSO_UPD_COUNT+4(%r5)     /* load update counter */
  82         tml     %r4,0x0001                      /* pending update ? loop */
  83         jnz     11b
  84         stck    24(%r15)                        /* Store TOD clock */
  85         lm      %r0,%r1,24(%r15)
  86         s       %r0,__VDSO_XTIME_STAMP(%r5)     /* TOD - cycle_last */
  87         sl      %r1,__VDSO_XTIME_STAMP+4(%r5)
  88         brc     3,12f
  89         ahi     %r0,-1
  90 12:     ms      %r0,__VDSO_TK_MULT(%r5)         /*  * tk->mult */
  91         lr      %r2,%r0
  92         l       %r0,__VDSO_TK_MULT(%r5)
  93         ltr     %r1,%r1
  94         mr      %r0,%r0
  95         jnm     13f
  96         a       %r0,__VDSO_TK_MULT(%r5)
  97 13:     alr     %r0,%r2
  98         al      %r0,__VDSO_XTIME_NSEC(%r5)      /*  + tk->xtime_nsec */
  99         al      %r1,__VDSO_XTIME_NSEC+4(%r5)
 100         brc     12,14f
 101         ahi     %r0,1
 102 14:     l       %r2,__VDSO_TK_SHIFT(%r5)        /* Timekeeper shift */
 103         srdl    %r0,0(%r2)                      /*  >> tk->shift */
 104         l       %r2,__VDSO_XTIME_SEC+4(%r5)
 105         cl      %r4,__VDSO_UPD_COUNT+4(%r5)     /* check update counter */
 106         jne     11b
 107         basr    %r5,0
 108 15:     ltr     %r0,%r0
 109         jnz     16f
 110         cl      %r1,20f-15b(%r5)
 111         jl      17f
 112 16:     ahi     %r2,1
 113         sl      %r1,20f-15b(%r5)
 114         brc     3,15b
 115         ahi     %r0,-1
 116         j       15b
 117 17:     st      %r2,0(%r3)                      /* store tp->tv_sec */
 118         st      %r1,4(%r3)                      /* store tp->tv_nsec */
 119 18:     lhi     %r2,0
 120         br      %r14
 121
 122         /* Fallback to system call */
 123 19:     lhi     %r1,__NR_clock_gettime
 124         svc     0
 125         br      %r14
 126
 127 20:     .long   1000000000
 128 21:     .long   _vdso_data - 0b
 129         .cfi_endproc
 130         .size   __kernel_clock_gettime,.-__kernel_clock_gettime