arch/powerpc/kernel/vdso32/vdso32.lds.S

   1
   2 /*
   3  * This is the infamous ld script for the 32 bits vdso
   4  * library
   5  */
   6 #include <asm/vdso.h>
   7
   8 /* Default link addresses for the vDSOs */
   9 OUTPUT_FORMAT("elf32-powerpc", "elf32-powerpc", "elf32-powerpc")
  10 OUTPUT_ARCH(powerpc:common)
  11 ENTRY(_start)
  12
  13 SECTIONS
  14 {
  15   . = VDSO32_LBASE + SIZEOF_HEADERS;
  16   .hash           : { *(.hash) }                        :text
  17   .gnu.hash       : { *(.gnu.hash) }
  18   .dynsym         : { *(.dynsym) }
  19   .dynstr         : { *(.dynstr) }
  20   .gnu.version    : { *(.gnu.version) }
  21   .gnu.version_d  : { *(.gnu.version_d) }
  22   .gnu.version_r  : { *(.gnu.version_r) }
  23
  24   .note           : { *(.note.*) }                      :text   :note
  25
  26   . = ALIGN (16);
  27   .text :
  28   {
  29     *(.text .stub .text.* .gnu.linkonce.t.*)
  30   }
  31   PROVIDE (__etext = .);
  32   PROVIDE (_etext = .);
  33   PROVIDE (etext = .);
  34
  35   . = ALIGN(8);
  36   __ftr_fixup : {
  37     *(__ftr_fixup)
  38   }
  39
  40 #ifdef CONFIG_PPC64
  41   . = ALIGN(8);
  42   __fw_ftr_fixup : {
  43     *(__fw_ftr_fixup)
  44   }
  45 #endif
  46
  47   /* Other stuff is appended to the text segment: */
  48   .rodata               : { *(.rodata .rodata.* .gnu.linkonce.r.*) }
  49   .rodata1              : { *(.rodata1) }
  50
  51   .eh_frame_hdr         : { *(.eh_frame_hdr) }          :text   :eh_frame_hdr
  52   .eh_frame             : { KEEP (*(.eh_frame)) }       :text
  53   .gcc_except_table     : { *(.gcc_except_table) }
  54   .fixup                : { *(.fixup) }
  55
  56   .dynamic              : { *(.dynamic) }               :text   :dynamic
  57   .got : { *(.got) }
  58   .plt : { *(.plt) }
  59
  60   _end = .;
  61   __end = .;
  62   PROVIDE (end = .);
  63
  64
  65   /* Stabs debugging sections are here too
  66    */
  67   .stab 0 : { *(.stab) }
  68   .stabstr 0 : { *(.stabstr) }
  69   .stab.excl 0 : { *(.stab.excl) }
  70   .stab.exclstr 0 : { *(.stab.exclstr) }
  71   .stab.index 0 : { *(.stab.index) }
  72   .stab.indexstr 0 : { *(.stab.indexstr) }
  73   .comment 0 : { *(.comment) }
  74   .debug 0 : { *(.debug) }
  75   .line 0 : { *(.line) }
  76
  77   .debug_srcinfo 0 : { *(.debug_srcinfo) }
  78   .debug_sfnames 0 : { *(.debug_sfnames) }
  79
  80   .debug_aranges 0 : { *(.debug_aranges) }
  81   .debug_pubnames 0 : { *(.debug_pubnames) }
  82
  83   .debug_info 0 : { *(.debug_info .gnu.linkonce.wi.*) }
  84   .debug_abbrev 0 : { *(.debug_abbrev) }
  85   .debug_line 0 : { *(.debug_line) }
  86   .debug_frame 0 : { *(.debug_frame) }
  87   .debug_str 0 : { *(.debug_str) }
  88   .debug_loc 0 : { *(.debug_loc) }
  89   .debug_macinfo 0 : { *(.debug_macinfo) }
  90
  91   .debug_weaknames 0 : { *(.debug_weaknames) }
  92   .debug_funcnames 0 : { *(.debug_funcnames) }
  93   .debug_typenames 0 : { *(.debug_typenames) }
  94   .debug_varnames 0 : { *(.debug_varnames) }
  95
  96   /DISCARD/ : { *(.note.GNU-stack) }
  97   /DISCARD/ : { *(.data .data.* .gnu.linkonce.d.* .sdata*) }
  98   /DISCARD/ : { *(.bss .sbss .dynbss .dynsbss) }
  99 }
 100
 101
 102 PHDRS
 103 {
 104   text PT_LOAD FILEHDR PHDRS FLAGS(5); /* PF_R|PF_X */
 105   note PT_NOTE FLAGS(4); /* PF_R */
 106   dynamic PT_DYNAMIC FLAGS(4); /* PF_R */
 107   eh_frame_hdr 0x6474e550; /* PT_GNU_EH_FRAME, but ld doesn't match the name */
 108 }
 109
 110
 111 /*
 112  * This controls what symbols we export from the DSO.
 113  */
 114 VERSION
 115 {
 116   VDSO_VERSION_STRING {
 117     global:
 118         __kernel_datapage_offset; /* Has to be there for the kernel to find */
 119         __kernel_get_syscall_map;
 120         __kernel_gettimeofday;
 121         __kernel_clock_gettime;
 122         __kernel_clock_getres;
 123         __kernel_get_tbfreq;
 124         __kernel_sync_dicache;
 125         __kernel_sync_dicache_p5;
 126         __kernel_sigtramp32;
 127         __kernel_sigtramp_rt32;
 128     local: *;
 129   };
 130 }