arch/powerpc/kernel/entry_64.S

   1 /*
   2  *  PowerPC version
   3  *    Copyright (C) 1995-1996 Gary Thomas (gdt@linuxppc.org)
   4  *  Rewritten by Cort Dougan (cort@cs.nmt.edu) for PReP
   5  *    Copyright (C) 1996 Cort Dougan <cort@cs.nmt.edu>
   6  *  Adapted for Power Macintosh by Paul Mackerras.
   7  *  Low-level exception handlers and MMU support
   8  *  rewritten by Paul Mackerras.
   9  *    Copyright (C) 1996 Paul Mackerras.
  10  *  MPC8xx modifications Copyright (C) 1997 Dan Malek (dmalek@jlc.net).
  11  *
  12  *  This file contains the system call entry code, context switch
  13  *  code, and exception/interrupt return code for PowerPC.
  14  *
  15  *  This program is free software; you can redistribute it and/or
  16  *  modify it under the terms of the GNU General Public License
  17  *  as published by the Free Software Foundation; either version
  18  *  2 of the License, or (at your option) any later version.
  19  */
  20
  21 #include <linux/errno.h>
  22 #include <asm/unistd.h>
  23 #include <asm/processor.h>
  24 #include <asm/page.h>
  25 #include <asm/mmu.h>
  26 #include <asm/thread_info.h>
  27 #include <asm/ppc_asm.h>
  28 #include <asm/asm-offsets.h>
  29 #include <asm/cputable.h>
  30 #include <asm/firmware.h>
  31 #include <asm/bug.h>
  32
  33 /*
  34  * System calls.
  35  */
  36         .section        ".toc","aw"
  37 .SYS_CALL_TABLE:
  38         .tc .sys_call_table[TC],.sys_call_table
  39
  40 /* This value is used to mark exception frames on the stack. */
  41 exception_marker:
  42         .tc     ID_72656773_68657265[TC],0x7265677368657265
  43
  44         .section        ".text"
  45         .align 7
  46
  47 #undef SHOW_SYSCALLS
  48
  49         .globl system_call_common
  50 system_call_common:
  51         andi.   r10,r12,MSR_PR
  52         mr      r10,r1
  53         addi    r1,r1,-INT_FRAME_SIZE
  54         beq-    1f
  55         ld      r1,PACAKSAVE(r13)
  56 1:      std     r10,0(r1)
  57         crclr   so
  58         std     r11,_NIP(r1)
  59         std     r12,_MSR(r1)
  60         std     r0,GPR0(r1)
  61         std     r10,GPR1(r1)
  62         ACCOUNT_CPU_USER_ENTRY(r10, r11)
  63         std     r2,GPR2(r1)
  64         std     r3,GPR3(r1)
  65         std     r4,GPR4(r1)
  66         std     r5,GPR5(r1)
  67         std     r6,GPR6(r1)
  68         std     r7,GPR7(r1)
  69         std     r8,GPR8(r1)
  70         li      r11,0
  71         std     r11,GPR9(r1)
  72         std     r11,GPR10(r1)
  73         std     r11,GPR11(r1)
  74         std     r11,GPR12(r1)
  75         std     r9,GPR13(r1)
  76         mfcr    r9
  77         mflr    r10
  78         li      r11,0xc01
  79         std     r9,_CCR(r1)
  80         std     r10,_LINK(r1)
  81         std     r11,_TRAP(r1)
  82         mfxer   r9
  83         mfctr   r10
  84         std     r9,_XER(r1)
  85         std     r10,_CTR(r1)
  86         std     r3,ORIG_GPR3(r1)
  87         ld      r2,PACATOC(r13)
  88         addi    r9,r1,STACK_FRAME_OVERHEAD
  89         ld      r11,exception_marker@toc(r2)
  90         std     r11,-16(r9)             /* "regshere" marker */
  91         li      r10,1
  92         stb     r10,PACASOFTIRQEN(r13)
  93         stb     r10,PACAHARDIRQEN(r13)
  94         std     r10,SOFTE(r1)
  95 #ifdef CONFIG_PPC_ISERIES
  96 BEGIN_FW_FTR_SECTION
  97         /* Hack for handling interrupts when soft-enabling on iSeries */
  98         cmpdi   cr1,r0,0x5555           /* syscall 0x5555 */
  99         andi.   r10,r12,MSR_PR          /* from kernel */
 100         crand   4*cr0+eq,4*cr1+eq,4*cr0+eq
 101         bne     2f
 102         b       hardware_interrupt_entry
 103 2:
 104 END_FW_FTR_SECTION_IFSET(FW_FEATURE_ISERIES)
 105 #endif
 106         mfmsr   r11
 107         ori     r11,r11,MSR_EE
 108         mtmsrd  r11,1
 109
 110 #ifdef SHOW_SYSCALLS
 111         bl      .do_show_syscall
 112         REST_GPR(0,r1)
 113         REST_4GPRS(3,r1)
 114         REST_2GPRS(7,r1)
 115         addi    r9,r1,STACK_FRAME_OVERHEAD
 116 #endif
 117         clrrdi  r11,r1,THREAD_SHIFT
 118         ld      r10,TI_FLAGS(r11)
 119         andi.   r11,r10,_TIF_SYSCALL_T_OR_A
 120         bne-    syscall_dotrace
 121 syscall_dotrace_cont:
 122         cmpldi  0,r0,NR_syscalls
 123         bge-    syscall_enosys
 124
 125 system_call:                    /* label this so stack traces look sane */
 126 /*
 127  * Need to vector to 32 Bit or default sys_call_table here,
 128  * based on caller's run-mode / personality.
 129  */
 130         ld      r11,.SYS_CALL_TABLE@toc(2)
 131         andi.   r10,r10,_TIF_32BIT
 132         beq     15f
 133         addi    r11,r11,8       /* use 32-bit syscall entries */
 134         clrldi  r3,r3,32
 135         clrldi  r4,r4,32
 136         clrldi  r5,r5,32
 137         clrldi  r6,r6,32
 138         clrldi  r7,r7,32
 139         clrldi  r8,r8,32
 140 15:
 141         slwi    r0,r0,4
 142         ldx     r10,r11,r0      /* Fetch system call handler [ptr] */
 143         mtctr   r10
 144         bctrl                   /* Call handler */
 145
 146 syscall_exit:
 147         std     r3,RESULT(r1)
 148 #ifdef SHOW_SYSCALLS
 149         bl      .do_show_syscall_exit
 150         ld      r3,RESULT(r1)
 151 #endif
 152         clrrdi  r12,r1,THREAD_SHIFT
 153
 154         /* disable interrupts so current_thread_info()->flags can't change,
 155            and so that we don't get interrupted after loading SRR0/1. */
 156         ld      r8,_MSR(r1)
 157         andi.   r10,r8,MSR_RI
 158         beq-    unrecov_restore
 159         mfmsr   r10
 160         rldicl  r10,r10,48,1
 161         rotldi  r10,r10,16
 162         mtmsrd  r10,1
 163         ld      r9,TI_FLAGS(r12)
 164         li      r11,-_LAST_ERRNO
 165         andi.   r0,r9,(_TIF_SYSCALL_T_OR_A|_TIF_SINGLESTEP|_TIF_USER_WORK_MASK|_TIF_PERSYSCALL_MASK)
 166         bne-    syscall_exit_work
 167         cmpld   r3,r11
 168         ld      r5,_CCR(r1)
 169         bge-    syscall_error
 170 syscall_error_cont:
 171         ld      r7,_NIP(r1)
 172         stdcx.  r0,0,r1                 /* to clear the reservation */
 173         andi.   r6,r8,MSR_PR
 174         ld      r4,_LINK(r1)
 175         /*
 176          * Clear RI before restoring r13.  If we are returning to
 177          * userspace and we take an exception after restoring r13,
 178          * we end up corrupting the userspace r13 value.
 179          */
 180         li      r12,MSR_RI
 181         andc    r11,r10,r12
 182         mtmsrd  r11,1                   /* clear MSR.RI */
 183         beq-    1f
 184         ACCOUNT_CPU_USER_EXIT(r11, r12)
 185         ld      r13,GPR13(r1)   /* only restore r13 if returning to usermode */
 186 1:      ld      r2,GPR2(r1)
 187         ld      r1,GPR1(r1)
 188         mtlr    r4
 189         mtcr    r5
 190         mtspr   SPRN_SRR0,r7
 191         mtspr   SPRN_SRR1,r8
 192         rfid
 193         b       .       /* prevent speculative execution */
 194
 195 syscall_error:
 196         oris    r5,r5,0x1000    /* Set SO bit in CR */
 197         neg     r3,r3
 198         std     r5,_CCR(r1)
 199         b       syscall_error_cont
 200
 201 /* Traced system call support */
 202 syscall_dotrace:
 203         bl      .save_nvgprs
 204         addi    r3,r1,STACK_FRAME_OVERHEAD
 205         bl      .do_syscall_trace_enter
 206         ld      r0,GPR0(r1)     /* Restore original registers */
 207         ld      r3,GPR3(r1)
 208         ld      r4,GPR4(r1)
 209         ld      r5,GPR5(r1)
 210         ld      r6,GPR6(r1)
 211         ld      r7,GPR7(r1)
 212         ld      r8,GPR8(r1)
 213         addi    r9,r1,STACK_FRAME_OVERHEAD
 214         clrrdi  r10,r1,THREAD_SHIFT
 215         ld      r10,TI_FLAGS(r10)
 216         b       syscall_dotrace_cont
 217
 218 syscall_enosys:
 219         li      r3,-ENOSYS
 220         b       syscall_exit
 221
 222 syscall_exit_work:
 223         /* If TIF_RESTOREALL is set, don't scribble on either r3 or ccr.
 224          If TIF_NOERROR is set, just save r3 as it is. */
 225
 226         andi.   r0,r9,_TIF_RESTOREALL
 227         beq+    0f
 228         REST_NVGPRS(r1)
 229         b       2f
 230 0:      cmpld   r3,r11          /* r10 is -LAST_ERRNO */
 231         blt+    1f
 232         andi.   r0,r9,_TIF_NOERROR
 233         bne-    1f
 234         ld      r5,_CCR(r1)
 235         neg     r3,r3
 236         oris    r5,r5,0x1000    /* Set SO bit in CR */
 237         std     r5,_CCR(r1)
 238 1:      std     r3,GPR3(r1)
 239 2:      andi.   r0,r9,(_TIF_PERSYSCALL_MASK)
 240         beq     4f
 241
 242         /* Clear per-syscall TIF flags if any are set.  */
 243
 244         li      r11,_TIF_PERSYSCALL_MASK
 245         addi    r12,r12,TI_FLAGS
 246 3:      ldarx   r10,0,r12
 247         andc    r10,r10,r11
 248         stdcx.  r10,0,r12
 249         bne-    3b
 250         subi    r12,r12,TI_FLAGS
 251
 252 4:      /* Anything else left to do? */
 253         andi.   r0,r9,(_TIF_SYSCALL_T_OR_A|_TIF_SINGLESTEP)
 254         beq     .ret_from_except_lite
 255
 256         /* Re-enable interrupts */
 257         mfmsr   r10
 258         ori     r10,r10,MSR_EE
 259         mtmsrd  r10,1
 260
 261         bl      .save_nvgprs
 262         addi    r3,r1,STACK_FRAME_OVERHEAD
 263         bl      .do_syscall_trace_leave
 264         b       .ret_from_except
 265
 266 /* Save non-volatile GPRs, if not already saved. */
 267 _GLOBAL(save_nvgprs)
 268         ld      r11,_TRAP(r1)
 269         andi.   r0,r11,1
 270         beqlr-
 271         SAVE_NVGPRS(r1)
 272         clrrdi  r0,r11,1
 273         std     r0,_TRAP(r1)
 274         blr
 275
 276
 277 /*
 278  * The sigsuspend and rt_sigsuspend system calls can call do_signal
 279  * and thus put the process into the stopped state where we might
 280  * want to examine its user state with ptrace.  Therefore we need
 281  * to save all the nonvolatile registers (r14 - r31) before calling
 282  * the C code.  Similarly, fork, vfork and clone need the full
 283  * register state on the stack so that it can be copied to the child.
 284  */
 285
 286 _GLOBAL(ppc_fork)
 287         bl      .save_nvgprs
 288         bl      .sys_fork
 289         b       syscall_exit
 290
 291 _GLOBAL(ppc_vfork)
 292         bl      .save_nvgprs
 293         bl      .sys_vfork
 294         b       syscall_exit
 295
 296 _GLOBAL(ppc_clone)
 297         bl      .save_nvgprs
 298         bl      .sys_clone
 299         b       syscall_exit
 300
 301 _GLOBAL(ppc32_swapcontext)
 302         bl      .save_nvgprs
 303         bl      .compat_sys_swapcontext
 304         b       syscall_exit
 305
 306 _GLOBAL(ppc64_swapcontext)
 307         bl      .save_nvgprs
 308         bl      .sys_swapcontext
 309         b       syscall_exit
 310
 311 _GLOBAL(ret_from_fork)
 312         bl      .schedule_tail
 313         REST_NVGPRS(r1)
 314         li      r3,0
 315         b       syscall_exit
 316
 317 /*
 318  * This routine switches between two different tasks.  The process
 319  * state of one is saved on its kernel stack.  Then the state
 320  * of the other is restored from its kernel stack.  The memory
 321  * management hardware is updated to the second process's state.
 322  * Finally, we can return to the second process, via ret_from_except.
 323  * On entry, r3 points to the THREAD for the current task, r4
 324  * points to the THREAD for the new task.
 325  *
 326  * Note: there are two ways to get to the "going out" portion
 327  * of this code; either by coming in via the entry (_switch)
 328  * or via "fork" which must set up an environment equivalent
 329  * to the "_switch" path.  If you change this you'll have to change
 330  * the fork code also.
 331  *
 332  * The code which creates the new task context is in 'copy_thread'
 333  * in arch/powerpc/kernel/process.c
 334  */
 335         .align  7
 336 _GLOBAL(_switch)
 337         mflr    r0
 338         std     r0,16(r1)
 339         stdu    r1,-SWITCH_FRAME_SIZE(r1)
 340         /* r3-r13 are caller saved -- Cort */
 341         SAVE_8GPRS(14, r1)
 342         SAVE_10GPRS(22, r1)
 343         mflr    r20             /* Return to switch caller */
 344         mfmsr   r22
 345         li      r0, MSR_FP
 346 #ifdef CONFIG_ALTIVEC
 347 BEGIN_FTR_SECTION
 348         oris    r0,r0,MSR_VEC@h /* Disable altivec */
 349         mfspr   r24,SPRN_VRSAVE /* save vrsave register value */
 350         std     r24,THREAD_VRSAVE(r3)
 351 END_FTR_SECTION_IFSET(CPU_FTR_ALTIVEC)
 352 #endif /* CONFIG_ALTIVEC */
 353         and.    r0,r0,r22
 354         beq+    1f
 355         andc    r22,r22,r0
 356         mtmsrd  r22
 357         isync
 358 1:      std     r20,_NIP(r1)
 359         mfcr    r23
 360         std     r23,_CCR(r1)
 361         std     r1,KSP(r3)      /* Set old stack pointer */
 362
 363 #ifdef CONFIG_SMP
 364         /* We need a sync somewhere here to make sure that if the
 365          * previous task gets rescheduled on another CPU, it sees all
 366          * stores it has performed on this one.
 367          */
 368         sync
 369 #endif /* CONFIG_SMP */
 370
 371         addi    r6,r4,-THREAD   /* Convert THREAD to 'current' */
 372         std     r6,PACACURRENT(r13)     /* Set new 'current' */
 373
 374         ld      r8,KSP(r4)      /* new stack pointer */
 375 BEGIN_FTR_SECTION
 376         clrrdi  r6,r8,28        /* get its ESID */
 377         clrrdi  r9,r1,28        /* get current sp ESID */
 378         clrldi. r0,r6,2         /* is new ESID c00000000? */
 379         cmpd    cr1,r6,r9       /* or is new ESID the same as current ESID? */
 380         cror    eq,4*cr1+eq,eq
 381         beq     2f              /* if yes, don't slbie it */
 382
 383         /* Bolt in the new stack SLB entry */
 384         ld      r7,KSP_VSID(r4) /* Get new stack's VSID */
 385         oris    r0,r6,(SLB_ESID_V)@h
 386         ori     r0,r0,(SLB_NUM_BOLTED-1)@l
 387
 388         /* Update the last bolted SLB */
 389         ld      r9,PACA_SLBSHADOWPTR(r13)
 390         li      r12,0
 391         std     r12,SLBSHADOW_STACKESID(r9) /* Clear ESID */
 392         std     r7,SLBSHADOW_STACKVSID(r9)  /* Save VSID */
 393         std     r0,SLBSHADOW_STACKESID(r9)  /* Save ESID */
 394
 395         slbie   r6
 396         slbie   r6              /* Workaround POWER5 < DD2.1 issue */
 397         slbmte  r7,r0
 398         isync
 399
 400 2:
 401 END_FTR_SECTION_IFSET(CPU_FTR_SLB)
 402         clrrdi  r7,r8,THREAD_SHIFT      /* base of new stack */
 403         /* Note: this uses SWITCH_FRAME_SIZE rather than INT_FRAME_SIZE
 404            because we don't need to leave the 288-byte ABI gap at the
 405            top of the kernel stack. */
 406         addi    r7,r7,THREAD_SIZE-SWITCH_FRAME_SIZE
 407
 408         mr      r1,r8           /* start using new stack pointer */
 409         std     r7,PACAKSAVE(r13)
 410
 411         ld      r6,_CCR(r1)
 412         mtcrf   0xFF,r6
 413
 414 #ifdef CONFIG_ALTIVEC
 415 BEGIN_FTR_SECTION
 416         ld      r0,THREAD_VRSAVE(r4)
 417         mtspr   SPRN_VRSAVE,r0          /* if G4, restore VRSAVE reg */
 418 END_FTR_SECTION_IFSET(CPU_FTR_ALTIVEC)
 419 #endif /* CONFIG_ALTIVEC */
 420
 421         /* r3-r13 are destroyed -- Cort */
 422         REST_8GPRS(14, r1)
 423         REST_10GPRS(22, r1)
 424
 425         /* convert old thread to its task_struct for return value */
 426         addi    r3,r3,-THREAD
 427         ld      r7,_NIP(r1)     /* Return to _switch caller in new task */
 428         mtlr    r7
 429         addi    r1,r1,SWITCH_FRAME_SIZE
 430         blr
 431
 432         .align  7
 433 _GLOBAL(ret_from_except)
 434         ld      r11,_TRAP(r1)
 435         andi.   r0,r11,1
 436         bne     .ret_from_except_lite
 437         REST_NVGPRS(r1)
 438
 439 _GLOBAL(ret_from_except_lite)
 440         /*
 441          * Disable interrupts so that current_thread_info()->flags
 442          * can't change between when we test it and when we return
 443          * from the interrupt.
 444          */
 445         mfmsr   r10             /* Get current interrupt state */
 446         rldicl  r9,r10,48,1     /* clear MSR_EE */
 447         rotldi  r9,r9,16
 448         mtmsrd  r9,1            /* Update machine state */
 449
 450 #ifdef CONFIG_PREEMPT
 451         clrrdi  r9,r1,THREAD_SHIFT      /* current_thread_info() */
 452         li      r0,_TIF_NEED_RESCHED    /* bits to check */
 453         ld      r3,_MSR(r1)
 454         ld      r4,TI_FLAGS(r9)
 455         /* Move MSR_PR bit in r3 to _TIF_SIGPENDING position in r0 */
 456         rlwimi  r0,r3,32+TIF_SIGPENDING-MSR_PR_LG,_TIF_SIGPENDING
 457         and.    r0,r4,r0        /* check NEED_RESCHED and maybe SIGPENDING */
 458         bne     do_work
 459
 460 #else /* !CONFIG_PREEMPT */
 461         ld      r3,_MSR(r1)     /* Returning to user mode? */
 462         andi.   r3,r3,MSR_PR
 463         beq     restore         /* if not, just restore regs and return */
 464
 465         /* Check current_thread_info()->flags */
 466         clrrdi  r9,r1,THREAD_SHIFT
 467         ld      r4,TI_FLAGS(r9)
 468         andi.   r0,r4,_TIF_USER_WORK_MASK
 469         bne     do_work
 470 #endif
 471
 472 restore:
 473         ld      r5,SOFTE(r1)
 474 #ifdef CONFIG_PPC_ISERIES
 475 BEGIN_FW_FTR_SECTION
 476         cmpdi   0,r5,0
 477         beq     4f
 478         /* Check for pending interrupts (iSeries) */
 479         ld      r3,PACALPPACAPTR(r13)
 480         ld      r3,LPPACAANYINT(r3)
 481         cmpdi   r3,0
 482         beq+    4f                      /* skip do_IRQ if no interrupts */
 483
 484         li      r3,0
 485         stb     r3,PACASOFTIRQEN(r13)   /* ensure we are soft-disabled */
 486         ori     r10,r10,MSR_EE
 487         mtmsrd  r10                     /* hard-enable again */
 488         addi    r3,r1,STACK_FRAME_OVERHEAD
 489         bl      .do_IRQ
 490         b       .ret_from_except_lite           /* loop back and handle more */
 491 4:
 492 END_FW_FTR_SECTION_IFSET(FW_FEATURE_ISERIES)
 493 #endif
 494         stb     r5,PACASOFTIRQEN(r13)
 495
 496         /* extract EE bit and use it to restore paca->hard_enabled */
 497         ld      r3,_MSR(r1)
 498         rldicl  r4,r3,49,63             /* r0 = (r3 >> 15) & 1 */
 499         stb     r4,PACAHARDIRQEN(r13)
 500
 501         ld      r4,_CTR(r1)
 502         ld      r0,_LINK(r1)
 503         mtctr   r4
 504         mtlr    r0
 505         ld      r4,_XER(r1)
 506         mtspr   SPRN_XER,r4
 507
 508         REST_8GPRS(5, r1)
 509
 510         andi.   r0,r3,MSR_RI
 511         beq-    unrecov_restore
 512
 513         stdcx.  r0,0,r1         /* to clear the reservation */
 514
 515         /*
 516          * Clear RI before restoring r13.  If we are returning to
 517          * userspace and we take an exception after restoring r13,
 518          * we end up corrupting the userspace r13 value.
 519          */
 520         mfmsr   r4
 521         andc    r4,r4,r0        /* r0 contains MSR_RI here */
 522         mtmsrd  r4,1
 523
 524         /*
 525          * r13 is our per cpu area, only restore it if we are returning to
 526          * userspace
 527          */
 528         andi.   r0,r3,MSR_PR
 529         beq     1f
 530         ACCOUNT_CPU_USER_EXIT(r2, r4)
 531         REST_GPR(13, r1)
 532 1:
 533         mtspr   SPRN_SRR1,r3
 534
 535         ld      r2,_CCR(r1)
 536         mtcrf   0xFF,r2
 537         ld      r2,_NIP(r1)
 538         mtspr   SPRN_SRR0,r2
 539
 540         ld      r0,GPR0(r1)
 541         ld      r2,GPR2(r1)
 542         ld      r3,GPR3(r1)
 543         ld      r4,GPR4(r1)
 544         ld      r1,GPR1(r1)
 545
 546         rfid
 547         b       .       /* prevent speculative execution */
 548
 549 /* Note: this must change if we start using the TIF_NOTIFY_RESUME bit */
 550 do_work:
 551 #ifdef CONFIG_PREEMPT
 552         andi.   r0,r3,MSR_PR    /* Returning to user mode? */
 553         bne     user_work
 554         /* Check that preempt_count() == 0 and interrupts are enabled */
 555         lwz     r8,TI_PREEMPT(r9)
 556         cmpwi   cr1,r8,0
 557         ld      r0,SOFTE(r1)
 558         cmpdi   r0,0
 559         crandc  eq,cr1*4+eq,eq
 560         bne     restore
 561         /* here we are preempting the current task */
 562 1:
 563         li      r0,1
 564         stb     r0,PACASOFTIRQEN(r13)
 565         stb     r0,PACAHARDIRQEN(r13)
 566         ori     r10,r10,MSR_EE
 567         mtmsrd  r10,1           /* reenable interrupts */
 568         bl      .preempt_schedule
 569         mfmsr   r10
 570         clrrdi  r9,r1,THREAD_SHIFT
 571         rldicl  r10,r10,48,1    /* disable interrupts again */
 572         rotldi  r10,r10,16
 573         mtmsrd  r10,1
 574         ld      r4,TI_FLAGS(r9)
 575         andi.   r0,r4,_TIF_NEED_RESCHED
 576         bne     1b
 577         b       restore
 578
 579 user_work:
 580 #endif
 581         /* Enable interrupts */
 582         ori     r10,r10,MSR_EE
 583         mtmsrd  r10,1
 584
 585         andi.   r0,r4,_TIF_NEED_RESCHED
 586         beq     1f
 587         bl      .schedule
 588         b       .ret_from_except_lite
 589
 590 1:      bl      .save_nvgprs
 591         li      r3,0
 592         addi    r4,r1,STACK_FRAME_OVERHEAD
 593         bl      .do_signal
 594         b       .ret_from_except
 595
 596 unrecov_restore:
 597         addi    r3,r1,STACK_FRAME_OVERHEAD
 598         bl      .unrecoverable_exception
 599         b       unrecov_restore
 600
 601 #ifdef CONFIG_PPC_RTAS
 602 /*
 603  * On CHRP, the Run-Time Abstraction Services (RTAS) have to be
 604  * called with the MMU off.
 605  *
 606  * In addition, we need to be in 32b mode, at least for now.
 607  *
 608  * Note: r3 is an input parameter to rtas, so don't trash it...
 609  */
 610 _GLOBAL(enter_rtas)
 611         mflr    r0
 612         std     r0,16(r1)
 613         stdu    r1,-RTAS_FRAME_SIZE(r1) /* Save SP and create stack space. */
 614
 615         /* Because RTAS is running in 32b mode, it clobbers the high order half
 616          * of all registers that it saves.  We therefore save those registers
 617          * RTAS might touch to the stack.  (r0, r3-r13 are caller saved)
 618          */
 619         SAVE_GPR(2, r1)                 /* Save the TOC */
 620         SAVE_GPR(13, r1)                /* Save paca */
 621         SAVE_8GPRS(14, r1)              /* Save the non-volatiles */
 622         SAVE_10GPRS(22, r1)             /* ditto */
 623
 624         mfcr    r4
 625         std     r4,_CCR(r1)
 626         mfctr   r5
 627         std     r5,_CTR(r1)
 628         mfspr   r6,SPRN_XER
 629         std     r6,_XER(r1)
 630         mfdar   r7
 631         std     r7,_DAR(r1)
 632         mfdsisr r8
 633         std     r8,_DSISR(r1)
 634         mfsrr0  r9
 635         std     r9,_SRR0(r1)
 636         mfsrr1  r10
 637         std     r10,_SRR1(r1)
 638
 639         /* Temporary workaround to clear CR until RTAS can be modified to
 640          * ignore all bits.
 641          */
 642         li      r0,0
 643         mtcr    r0
 644
 645 #ifdef CONFIG_BUG
 646         /* There is no way it is acceptable to get here with interrupts enabled,
 647          * check it with the asm equivalent of WARN_ON
 648          */
 649         lbz     r0,PACASOFTIRQEN(r13)
 650 1:      tdnei   r0,0
 651         EMIT_BUG_ENTRY 1b,__FILE__,__LINE__,BUGFLAG_WARNING
 652 #endif
 653
 654         /* Hard-disable interrupts */
 655         mfmsr   r6
 656         rldicl  r7,r6,48,1
 657         rotldi  r7,r7,16
 658         mtmsrd  r7,1
 659
 660         /* Unfortunately, the stack pointer and the MSR are also clobbered,
 661          * so they are saved in the PACA which allows us to restore
 662          * our original state after RTAS returns.
 663          */
 664         std     r1,PACAR1(r13)
 665         std     r6,PACASAVEDMSR(r13)
 666
 667         /* Setup our real return addr */
 668         LOAD_REG_ADDR(r4,.rtas_return_loc)
 669         clrldi  r4,r4,2                 /* convert to realmode address */
 670         mtlr    r4
 671
 672         li      r0,0
 673         ori     r0,r0,MSR_EE|MSR_SE|MSR_BE|MSR_RI
 674         andc    r0,r6,r0
 675
 676         li      r9,1
 677         rldicr  r9,r9,MSR_SF_LG,(63-MSR_SF_LG)
 678         ori     r9,r9,MSR_IR|MSR_DR|MSR_FE0|MSR_FE1|MSR_FP
 679         andc    r6,r0,r9
 680         ori     r6,r6,MSR_RI
 681         sync                            /* disable interrupts so SRR0/1 */
 682         mtmsrd  r0                      /* don't get trashed */
 683
 684         LOAD_REG_ADDR(r4, rtas)
 685         ld      r5,RTASENTRY(r4)        /* get the rtas->entry value */
 686         ld      r4,RTASBASE(r4)         /* get the rtas->base value */
 687
 688         mtspr   SPRN_SRR0,r5
 689         mtspr   SPRN_SRR1,r6
 690         rfid
 691         b       .       /* prevent speculative execution */
 692
 693 _STATIC(rtas_return_loc)
 694         /* relocation is off at this point */
 695         mfspr   r4,SPRN_SPRG3           /* Get PACA */
 696         clrldi  r4,r4,2                 /* convert to realmode address */
 697
 698         mfmsr   r6
 699         li      r0,MSR_RI
 700         andc    r6,r6,r0
 701         sync
 702         mtmsrd  r6
 703
 704         ld      r1,PACAR1(r4)           /* Restore our SP */
 705         LOAD_REG_IMMEDIATE(r3,.rtas_restore_regs)
 706         ld      r4,PACASAVEDMSR(r4)     /* Restore our MSR */
 707
 708         mtspr   SPRN_SRR0,r3
 709         mtspr   SPRN_SRR1,r4
 710         rfid
 711         b       .       /* prevent speculative execution */
 712
 713 _STATIC(rtas_restore_regs)
 714         /* relocation is on at this point */
 715         REST_GPR(2, r1)                 /* Restore the TOC */
 716         REST_GPR(13, r1)                /* Restore paca */
 717         REST_8GPRS(14, r1)              /* Restore the non-volatiles */
 718         REST_10GPRS(22, r1)             /* ditto */
 719
 720         mfspr   r13,SPRN_SPRG3
 721
 722         ld      r4,_CCR(r1)
 723         mtcr    r4
 724         ld      r5,_CTR(r1)
 725         mtctr   r5
 726         ld      r6,_XER(r1)
 727         mtspr   SPRN_XER,r6
 728         ld      r7,_DAR(r1)
 729         mtdar   r7
 730         ld      r8,_DSISR(r1)
 731         mtdsisr r8
 732         ld      r9,_SRR0(r1)
 733         mtsrr0  r9
 734         ld      r10,_SRR1(r1)
 735         mtsrr1  r10
 736
 737         addi    r1,r1,RTAS_FRAME_SIZE   /* Unstack our frame */
 738         ld      r0,16(r1)               /* get return address */
 739
 740         mtlr    r0
 741         blr                             /* return to caller */
 742
 743 #endif /* CONFIG_PPC_RTAS */
 744
 745 _GLOBAL(enter_prom)
 746         mflr    r0
 747         std     r0,16(r1)
 748         stdu    r1,-PROM_FRAME_SIZE(r1) /* Save SP and create stack space */
 749
 750         /* Because PROM is running in 32b mode, it clobbers the high order half
 751          * of all registers that it saves.  We therefore save those registers
 752          * PROM might touch to the stack.  (r0, r3-r13 are caller saved)
 753          */
 754         SAVE_8GPRS(2, r1)
 755         SAVE_GPR(13, r1)
 756         SAVE_8GPRS(14, r1)
 757         SAVE_10GPRS(22, r1)
 758         mfcr    r4
 759         std     r4,_CCR(r1)
 760         mfctr   r5
 761         std     r5,_CTR(r1)
 762         mfspr   r6,SPRN_XER
 763         std     r6,_XER(r1)
 764         mfdar   r7
 765         std     r7,_DAR(r1)
 766         mfdsisr r8
 767         std     r8,_DSISR(r1)
 768         mfsrr0  r9
 769         std     r9,_SRR0(r1)
 770         mfsrr1  r10
 771         std     r10,_SRR1(r1)
 772         mfmsr   r11
 773         std     r11,_MSR(r1)
 774
 775         /* Get the PROM entrypoint */
 776         ld      r0,GPR4(r1)
 777         mtlr    r0
 778
 779         /* Switch MSR to 32 bits mode
 780          */
 781         mfmsr   r11
 782         li      r12,1
 783         rldicr  r12,r12,MSR_SF_LG,(63-MSR_SF_LG)
 784         andc    r11,r11,r12
 785         li      r12,1
 786         rldicr  r12,r12,MSR_ISF_LG,(63-MSR_ISF_LG)
 787         andc    r11,r11,r12
 788         mtmsrd  r11
 789         isync
 790
 791         /* Restore arguments & enter PROM here... */
 792         ld      r3,GPR3(r1)
 793         blrl
 794
 795         /* Just make sure that r1 top 32 bits didn't get
 796          * corrupt by OF
 797          */
 798         rldicl  r1,r1,0,32
 799
 800         /* Restore the MSR (back to 64 bits) */
 801         ld      r0,_MSR(r1)
 802         mtmsrd  r0
 803         isync
 804
 805         /* Restore other registers */
 806         REST_GPR(2, r1)
 807         REST_GPR(13, r1)
 808         REST_8GPRS(14, r1)
 809         REST_10GPRS(22, r1)
 810         ld      r4,_CCR(r1)
 811         mtcr    r4
 812         ld      r5,_CTR(r1)
 813         mtctr   r5
 814         ld      r6,_XER(r1)
 815         mtspr   SPRN_XER,r6
 816         ld      r7,_DAR(r1)
 817         mtdar   r7
 818         ld      r8,_DSISR(r1)
 819         mtdsisr r8
 820         ld      r9,_SRR0(r1)
 821         mtsrr0  r9
 822         ld      r10,_SRR1(r1)
 823         mtsrr1  r10
 824
 825         addi    r1,r1,PROM_FRAME_SIZE
 826         ld      r0,16(r1)
 827         mtlr    r0
 828         blr