arch/mips/boot/compressed/ld.script

   1 /*
   2  * ld.script for compressed kernel support of MIPS
   3  *
   4  * Copyright (C) 2009 Lemote Inc.
   5  * Author: Wu Zhangjin <wuzhanjing@gmail.com>
   6  * Copyright (C) 2010 "Wu Zhangjin" <wuzhanjing@gmail.com>
   7  */
   8
   9 OUTPUT_ARCH(mips)
  10 ENTRY(start)
  11 PHDRS {
  12         text PT_LOAD FLAGS(7); /* RWX */
  13 }
  14 SECTIONS
  15 {
  16         /* Text and read-only data */
  17         /* . = VMLINUZ_LOAD_ADDRESS; */
  18         .text : {
  19                 *(.text)
  20                 *(.rodata)
  21         }: text
  22         /* End of text section */
  23
  24         /* Writable data */
  25         .data : {
  26                 *(.data)
  27                 /* Put the compressed image here */
  28                 __image_begin = .;
  29                 *(.image)
  30                 __image_end = .;
  31                 CONSTRUCTORS
  32                 . = ALIGN(16);
  33         }
  34         __appended_dtb = .;
  35         /* leave space for appended DTB */
  36         . += 0x100000;
  37
  38         _edata = .;
  39         /* End of data section */
  40
  41         /* BSS */
  42         .bss : {
  43                 *(.bss)
  44         }
  45         . = ALIGN(16);
  46         _end = .;
  47
  48         /* Sections to be discarded */
  49         /DISCARD/ : {
  50                 *(.MIPS.options)
  51                 *(.options)
  52                 *(.pdr)
  53                 *(.reginfo)
  54                 *(.comment)
  55                 *(.note)
  56         }
  57 }